标题: [动画特效]多个弹珠同时跳动
[打印本页]
作者: netbenton
时间: 2009-6-1 10:51
标题: [动画特效]多个弹珠同时跳动
@echo off&setlocal enabledelayedexpansion
mode con: cols=81 lines=30&color 1f
for /l %%i in (1 1 39) do set "spa= !spa!"
::在这个变量定义弹珠个数
set curs=a1 a2 a3 a4 a5 a6 a7
::随机定位
for %%a in (%curs%) do (
set /a %%as=1,%%ah=1
set /a %%av=!random!%%40*2,%%ai=!random!%%30
)
:loop
(
for %%a in (%curs%) do (
set/a %%ai+=%%as,%%av+=%%ah,#v=%%av+2
for /f "tokens=1,2,3" %%b in ("!%%av! !#v! ec!%%ai!") do (
if defined %%d (set ec!%%ai!=!%%d:~,%%b!●!%%d:~%%c!) else (set ec!%%ai!=!spa:~,%%b!●!spa:~%%c!)
)
)
cls&for /l %%i in (0 1 28) do echo;!ec%%i!
set/p=!ec29!<nul
for %%a in (%curs%) do (
set ec!%%ai!=
if !%%av! geq 78 set %%ah=-2
if !%%av! leq 0 set %%ah=2
if !%%ai! leq 0 set %%as=1
if !%%ai! geq 29 set %%as=-1
)
for /l %%i in (1 1 120) do ver>nul
goto :loop
)
[
Last edited by netbenton on 2009-6-1 at 09:52 ]
作者: kennyfan
时间: 2009-6-1 11:42
谢谢分享,又一新的特破!
作者: tianzizhi
时间: 2009-6-1 13:15
水平高,实在是高!
作者: rubble
时间: 2009-6-21 22:54
标题: 没有做不到,只有想不到!
没有做不到,只有想不到!
作者: songkingman
时间: 2009-6-24 01:15
GOOD
作者: chenall
时间: 2009-6-24 04:02
好强,这也行..
作者: moniuming
时间: 2009-6-24 08:37
太强悍了,加分!!!