标题: [分享]%var%代替语句执行 [打印本页]
作者: 523066680 时间: 2008-12-19 10:46 标题: [分享]%var%代替语句执行
文/523066680
发表于:http://www.cn-dos.net/forum/viewthread.php?tid=45240&fpage=1
首先,声明的是这个用法并不是我发明的,我只是也想到了同样的方法而已,为了发扬这个方法,所以
发表文章.
第一次想到这样玩是在做贪吃蛇的时候,相关分析:http://www.cn-dos.net/forum/view ... hlight=%2B523066680 23楼
这里是相关部分:
关于记录某个"编号"的点的坐标:
set cut%i%="set /a a=%line%,b=%col%,c=%C2%" 这整个定义三个变量的语句都放在一个
编号变量里面了,嘿嘿,利用批处理的性质,之后要用到这三个变量时,一句 !cut%i%:"=! 就相当于执行
set /a a=%line%,b=%col%,c=%C2% 接下来就直接%a% %b% %c%表示,而非!var%num%!或者%%var%num%%%.
可见适当的利用这个性质可以省很多事儿的.set cut%i%="set /a a=%line%,b=%col%,c=%C2%" 这整个定义三个变量的语句都放在一个
编号变量里面了,嘿嘿,利用批处理的性质,之后要用到这三个变量时,一句 !cut%i%:"=! 就相当于执行
set /a a=%line%,b=%col%,c=%C2% 接下来就直接%a% %b% %c%表示,而非!var%num%!或者%%var%num%%%.
举个简单的例子吧,ping,一般的延迟都是用ping(尤其是特效) 经常会看到一些脚本多处使用到ping
假如够懒,就可以用 %变量% 取代ping 像这样:
set "ping=ping -n 2 127.1>nul"
%ping%
pause
改变ping 的时间,可以用 %ping: 2 = 3 %
接下来的多出ping 就直接%ping%了 呵呵
不过感觉也太懒了点. 这只是一个示范,感觉是长一点的句子的话比较体现优势.当然特殊字符也是一个问题.
(这里不讨论)
我们还可以用 %var% 执行 for 语句,还可以是多重镶套,我发现的有趣的是for 的结尾处的括号用
%var2% 表示仍然可行,所以 还可以用另一个 for 语句 给这个%var% 设定多重镶套, 然后设定结尾括号个数...
应用例子可以见: http://www.cn-dos.net/forum/view ... id=8HBO3h#pid317040 27楼
以及 [已结]怎样生成一个纯数字的密码字典
http://www.cn-dos.net/forum/view ... id=8HBO3h#pid317042 6楼
@echo off &setlocal enabledelayedexpansion
set /p "n=输入位数,最大为9: "
for /l %%x in (1,1,%n%) do (
set fo="for %%%%x in (0 1 2 3 4 5 6 7 8 9) do (!fo!"
set end="!end!)"
set echo=!echo! %%%%x
)
%fo:"=%
echo %echo%
%end:"=%
pause
我说过了,这个方法不是我发明的,我只是发现并且作为一个提倡者,我查了一下系统自带的批处理set /p "n=输入位数,最大为9: "
for /l %%x in (1,1,%n%) do (
set fo="for %%%%x in (0 1 2 3 4 5 6 7 8 9) do (!fo!"
set end="!end!)"
set echo=!echo! %%%%x
)
%fo:"=%
echo %echo%
%end:"=%
pause
其中一个名为 msdtcvtr.bat (纯英文的...汗)
里面的一个例子也很好的, 这里是开头部分
@echo off
rem *************** start of 'main'
set DEBUG=0
if "%DEBUG%"=="1" (set TRACE=echo) else (set TRACE=rem)
rem Note that right now there is a bug in tracerpt.exe cause of which you might want to use tracefmt.exe instead.
rem set the value 1 if you want to use tracefmt.exe instead
set USE_TRACE_FMT=1
%TRACE% The value of variable USE_TRACE_FMT is %USE_TRACE_FMT%
:
:
大家看到 TRACE 这个变量了吧,他决定了是否向用户显示一句话呢,我觉得这是个特别号的例子.
因为后面有多处
%TRACE% "可能要显示的信息"
假如这些全都用if 来判断是否显示,估计代码....
[ Last edited by 523066680 on 2008-12-19 at 10:52 ]
作者: wxcute 时间: 2008-12-19 11:13
还是你用得比较好。
我在修改你的贪吃蛇的时候也用了一个，不过我的就有点儿画蛇添足的味道了。
作者: 523066680 时间: 2008-12-20 16:52
居然没人看...... 哎 我太小白 了
尽做些吃力不讨好的事
作者: zjw767676 时间: 2009-4-17 11:27
酒香不怕巷子深！我从bathome赶来顶你了！！O(∩_∩)O~
作者: netbenton 时间: 2009-4-17 12:20
学了就要用
::BAT 代码效率测试程序，Made by Benton 2009-04-14
::测试单行BAT命令的用时，并可以把测试结果存入文件
::
@echo off&setlocal enabledelayedexpansion
set 次=1000
:rep
set 命=
echo.&echo.&echo.&echo.
echo. 测试代码运行时间
echo.
set /p 命=输入要测试的代码行：
if "!命!"=="" goto :eof
set 止=%起%
set 叠加=0
(echo set 起=%%time%%
for /l %%a in (1,1,%次%) do echo !命!
echo set 止=%%time%%
echo :sub)>temp.bat
:lp
call temp.bat
echo.&echo.
set "起=%起: =0%"
set "止=%止: =0%"
set/a #起=^(1%起:~0,2%-100^)*60*60*100+^(1%起:~3,2%-100^)*60*100+^(1%起:~6,2%-100^)*100+1%起:~9%-100
set/a #止=^(1%止:~0,2%-100^)*60*60*100+^(1%止:~3,2%-100^)*60*100+^(1%止:~6,2%-100^)*100+1%止:~9%-100
set/a 用时=#止-#起
echo.!命!
echo.运行%次%次用时 %用时%毫秒
echo.&echo.
set/a 重复+=1,叠加+=用时
set/p 止=是否保存记录[Y][R]:
if /i "!止!"=="R" goto :lp
set /a 用时=叠加/重复,重复=0
echo.
if /i "!止!"=="Y" (echo.!命!>>test_comm.txt&echo.=== %次% %用时% >>test_comm.txt&echo.已经存入...)
goto :rep
::测试单行BAT命令的用时，并可以把测试结果存入文件
::
@echo off&setlocal enabledelayedexpansion
set 次=1000
:rep
set 命=
echo.&echo.&echo.&echo.
echo. 测试代码运行时间
echo.
set /p 命=输入要测试的代码行：
if "!命!"=="" goto :eof
set 止=%起%
set 叠加=0
(echo set 起=%%time%%
for /l %%a in (1,1,%次%) do echo !命!
echo set 止=%%time%%
echo :sub)>temp.bat
:lp
call temp.bat
echo.&echo.
set "起=%起: =0%"
set "止=%止: =0%"
set/a #起=^(1%起:~0,2%-100^)*60*60*100+^(1%起:~3,2%-100^)*60*100+^(1%起:~6,2%-100^)*100+1%起:~9%-100
set/a #止=^(1%止:~0,2%-100^)*60*60*100+^(1%止:~3,2%-100^)*60*100+^(1%止:~6,2%-100^)*100+1%止:~9%-100
set/a 用时=#止-#起
echo.!命!
echo.运行%次%次用时 %用时%毫秒
echo.&echo.
set/a 重复+=1,叠加+=用时
set/p 止=是否保存记录[Y][R]:
if /i "!止!"=="R" goto :lp
set /a 用时=叠加/重复,重复=0
echo.
if /i "!止!"=="Y" (echo.!命!>>test_comm.txt&echo.=== %次% %用时% >>test_comm.txt&echo.已经存入...)
goto :rep
作者: 523066680 时间: 2009-4-18 05:55
网吧匆匆之间，我的大脑嗡的一下，愣是没看出来怎么用。
[ Last edited by 523066680 on 2009-4-18 at 05:57 ]
作者: netbenton 时间: 2009-4-18 06:15
运行后要求输入一行批处理命令，
输入命令回车后，（直接回车为退出）
即测试出该命令运行1000次所用时间（毫秒）
然后出现的提示符：
是否保存记录[Y][R]:
输入y把刚测试的结果存入到文档，
输入r则重测试一次，多次测试后存入时，会取平均结果
输入其它则又回到重新输入命令行状态。
=================
该工具可测度对比出用什么命令更高效
但是有些命令是测不了的，如：exit，会直接退出了。
作者: 523066680 时间: 2009-4-18 21:02
哦，明白了，发此贴做个回复。
作者: hugreen 时间: 2009-4-18 22:28
谢谢分享
收藏了
TRACE那个例子很不错，令人联想到C++对应的TRACE功能，算法写得越好，批处理和高级语言靠得越近
作者: yishanju 时间: 2009-4-18 23:02
初学批处理写的是命令，后写的是命令集合，再往下精通了就会当成一们编程语言来写了