中国DOS联盟

『楼 主』:

@echo off

title made by 523066680 2008-08-08

::这一版本由www.cn-dos.net & www.bathome.cn 成员523066680编辑

setlocal enabledelayedexpansion

color 0a

set 01=●●●●

set 02=●    ●

set 03=●    ●

set 04=●    ●

set 05=●●●●

set 11=   ●   

set 12=   ●   

set 13=   ●   

set 14=   ●   

set 15=   ●   

set 21=●●●●

set 22=      ●

set 23=●●●●

set 24=●      

set 25=●●●●

set 31=●●●●

set 32=      ●

set 33=●●●●

set 34=      ●

set 35=●●●●

set 41=●    ●

set 42=●    ●

set 43=●●●●

set 44=      ●

set 45=      ●

set 51=●●●●

set 52=●      

set 53=●●●●

set 54=      ●

set 55=●●●●

set 61=●●●●

set 62=●      

set 63=●●●●

set 64=●    ●

set 65=●●●●

set 71=●●●●

set 72=      ●

set 73=      ●

set 74=      ●

set 75=      ●

set 81=●●●●

set 82=●    ●

set 83=●●●●

set 84=●    ●

set 85=●●●●

set 91=●●●●

set 92=●    ●

set 93=●●●●

set 94=      ●

set 95=●●●●

:a

for /f %%a in ('time /t') do set t0=%%a&set /a t1=!t0:~0,1!,t2=!t0:~1,1!

for /l %%a in (1,1,5) do (

set hang%%a=!%t1%%%a! !%t2%%%a!  + !%time:~3,1%%%a! !%time:~4,1%%%a!  + !%time:~6,1%%%a! !%time:~7,1%%%a!

)

ping -n 1 -w 500 0.0.0.1>nul

cls

echo,

echo,

echo,   %hang1%

echo,    %hang2%

echo,     %hang3%

echo,      %hang4%

echo,       %hang5%

echo,

goto :a

此帖被 +13 点积分        点击查看详情    评分人：【 radem 】 分数： +2  时间：2008-7-28 11:40 评分人：【 moniuming 】 分数： +8  时间：2008-7-28 11:54 评分人：【 BC 】 分数： +1  时间：2008-8-15 20:48 评分人：【 acaigg 】 分数： +1  时间：2011-1-6 21:48 评分人：【 cyn01livecn 】 分数： +1  时间：2011-1-18 12:31

@echo off

setlocal enabledelayedexpansion

for /l %%a in (1,1,10) do (

set /a  n=%%a+%%a

echo !n!

)

pause

@echo off

for /l %%a in (1,1,10) do (

set /a n=%%a+%%a

call,echo,%%n%%

)

pause

@echo off

setlocal enabledelayedexpansion

for /l %%a in (1,1,10) do (

echo  %time%  !time!



ping -n 1 127.1>nul

)

pause

@echo off

setlocal enabledelayedexpansion

set n=0

set /a n+=1 &echo %n% &echo !n!

::上面的句子虽然用了&但始终是同一句，%n%还是代表句子前面建立的n.!n!会是+1后的n

echo %n%

::这是下一句，%n%已经是改变后的了。

pause

很多百分号，系统会难以区分，于是启用变量延迟，用百分号和
感叹号 达到区分的作用。