标题: 【讨论】关于注释：：的疑问 [打印本页]
作者: plp626 时间: 2008-5-11 08:24 标题: 【讨论】关于注释：：的疑问
大家都知道::比rem要解释得快，所以注释一直用::来代替rem
我以前一直以为cmd遇到::后，其后的字符视而不见了（非复合句里），但是我今天发现自己错了:
| Quote: | |||||||||||||
|
大家讨论下cmd怎么解释这个::的？
---------------------
再赋个语法错误的代码：
| Quote: | |
|
[ Last edited by plp626 on 2008-5-11 at 09:00 AM ]
作者: bat-zw 时间: 2008-5-11 08:35
兄弟不妨在::后加个空格试试看：:: set...
作者: plp626 时间: 2008-5-11 08:40
| Quote: | |
|
仍为语法错误：
@echo off
call:r 2121212
pause
:r
set t=%1
:: set t=%t:*=%
echo %t%
pause
CMD不会因加了空格对后面内容视而不见，它还要解释，这ＣＭＤ真是个ＳＢcall:r 2121212
pause
:r
set t=%1
:: set t=%t:*=%
echo %t%
pause
作者: bat-zw 时间: 2008-5-11 08:50
@echo off
call:r 2121212
pause
:r
set t=%1
rem set t=%t:*=%
echo %t%
pause
这样也是一样。call:r 2121212
pause
:r
set t=%1
rem set t=%t:*=%
echo %t%
pause
@echo off
call:r 2121212
pause
:r
:: set t=%t:*=%
set t=%1
echo %t%
pause
而这样就没问题了，真的是怪了。call:r 2121212
pause
:r
:: set t=%t:*=%
set t=%1
echo %t%
pause
[ Last edited by zw19750516 on 2008-5-11 at 08:54 AM ]
作者: plp626 时间: 2008-5-11 08:50
进一步发现：
| Quote: | |
|
作者: regvip2008 时间: 2008-5-11 09:58
哈哈，谢谢plp626兄，发现了一个这么有趣的现象！先顶一个！！
我个人认为，应该是cmd在读取到::标签时，若发现其后为SET为某个变量进行字符替换，当遇到set t=%t:*=%这个严重的语法错误时，将不会再返回错误，而直接退出，然而造成set t=%t:*=%这个严重的语法错误是“*”在作怪！所以用set t=%t:^*=%就可以运行了！
作者: plp626 时间: 2008-5-11 14:55
我认为这是批文件注释的一个bug，有谁不同意？？？
[ Last edited by plp626 on 2008-5-11 at 02:58 PM ]
作者: slore 时间: 2008-5-11 14:58
不算吧？
CMD没有那个语句说明这个是注释语句……
你用rem看看有错没？
作者: plp626 时间: 2008-5-11 14:59
| Quote: | |
|
4楼的，用rem和::效果一样。。。
作者: slore 时间: 2008-5-11 15:10
哦。
注释和echo我觉得一样的处理机制
rem虽然不回显，但是还是支持变量的引用。
所以在没有t变量的时候你::掉，rem点没有关系，但是你set t后，
对rem或者echo的内容是要检查的。
所以我觉得echo的了的，应该都可以rem……
rem的有错的，理论上echo也应该有错。
作者: xzyx 时间: 2008-5-11 19:26
嗯，我说一下我的看法：
为什么“set t=%t:*=%”这句会错，是因为批处理有这样的语法--“set mypath=%mypath:*\=%”，意思是将第一个“\”之前的内容清空。也就是说“*”在“%%”中是被赋予特殊含义的。
而在变量延迟开启的情况下，“set t=!t:*=!”这句的结果是“t:*=”，也就是说“*”在“!!”中没有被赋予特殊含义。
那么问题究竟处在哪里呢？应该还是出现在符号的优先级上。也就是说“*”和“%”优先级大于“:”。
那么为什么“rem”也会出错呢？因为批处理是要进行预处理的，而在符号处理阶段已经出错。
作者: xzyx 时间: 2008-5-11 19:40
这只是批处理运行的机制，而不应该理解为bug。
作者: knoppix7 时间: 2008-5-11 19:44
难道传说中的预扩充还在起作用.....
作者: plp626 时间: 2008-5-11 20:58
| Quote: | |
|
| Quote: | |
|
那谁分析下command解释代码的内部机制，分几个阶段，每个阶段干什么，
优先级。。？
作者: pooronce 时间: 2008-5-11 21:10
测试了一下，发现不管加不加引号，是不是先把环境变量延迟打开都是这样，赶明儿再到2003下面试一下
……问题应该出现在cmd的解释执行机制不同的，可能它最先就是把变量解释出来的，对于注释这里，应该的确算是bug。 有条件的试下在vista及win2008里面这个bug还存在不
作者: xzyx 时间: 2008-5-12 09:26
如果你对脱字字符“^”的处理机制比较熟悉那么可以接着阅读，否
则请先参考脱字字符的相关文章。
最近忙着毕设，不过还是难忘批处理，有事没事还是会思考一些东西。这不，回来看看大家顺便写了篇文章。本文以原来的一篇文章为基础，本以为很快会写完，没想到写了一整天，真是耽误事，哎。
一、预处理究竟要做什么？
根据我的经验，预处理要做的是变量值的替换和特殊符号的处
理。究竟先执行哪个操作呢，我认为要先进行变量值的替换。理由
有三：
1、 从逻辑上看
set var=2&echo %var%
类似于这样的语句，如果说先进行特殊符号处理的话，势必要先处
理符号“&”，而“&”是用来连接两条命令的，这样一来该行就理
所应当的被理解为两句，那么我们还要变量延迟干嘛。这里应该是
先对变量var赋值，然后处理特殊符号“&”。
2、从运行结果看
@echo off
set var=^^^>
echo %var%
pause
这句“set var=^^^>”首先也会被预处理，预处理之后var的值为
“^>”。
本例的输出结果是“>”，因此可以证明系统先将变量的值替换为
“^>”然后再处理特殊符号“^”。
3、从变量替换上看
@echo off
set ^&var=hero
echo %&var%
pause
结果：显示“hero”
这也说明变量的替换先于特殊符号的处理。
二、启动了变量延迟之后预处理又是如何进行呢？
我的看法是这样的：如果语句中存在英文叹号“!”则会被预
处理两次，其它情况仍然是预处理一次。由于脱字字符比较特殊，
，因此在此借助该符号写几个例子说明一下。
（一）
@echo off
echo !^^^^^>
setlocal enabledelayedexpansion
echo !^^^^^>
pause
两个echo语句的结果不同。下面做一下分析：
对于第一个echo语句，变量延迟没有开启，进行预处理的时候该句
就被预处理为“echo !^^>”，这也就是输出的结果。由此可见预
处理只进行了一次。
对于第二个echo语句，此时变量延迟开启，由于有“!”存在，首
先进行一次预处理得到“echo !^^>”，再进行一次得到“echo ^>
”，结果也是如此。
之所以没有输出叹号，是因为开启了变量延迟，叹号就变为了特殊
符号。
（二）
@echo off
setlocal enabledelayedexpansion
set var=hero
echo !var!
pause
像这里的“echo !var!”不是没有被预处理，而是被预处理了两次
。看下面的这段代码就可以理解了。
@echo off
setlocal enabledelayedexpansion
set var=hero
echo !var!^^^^^>
pause
运行的结果为：“hero^>”。我们来分析一下，进行第一次预处理
时，由于“!var!”，因此先不替换变量值而进行特殊符号的处理
，处理完后就成了“echo !var!^^>”；之后再进行一次预处理，
此时就要替换“!var!”了，处理完后就成了“echo hero^>”。
（三）
我们再来看看当变量延迟开启时语句中不存在英文叹号的情况。
@echo off
echo ^^^^^>
setlocal enabledelayedexpansion
echo ^^^^^>
pause
@echo off
set var=hero
echo %var%^^^^^>
setlocal enabledelayedexpansion
echo %var%^^^^^>
pause
怎么样，也就是说如果没有“!”就不会进行第二次处理。
（四）
对于!!型，特殊符号的处理是在变量替换之前进行的。
例、
@echo off
setlocal enabledelayedexpansion
set ^&var=hero
echo !&var!
pause
这段代码运行结果是错误的。
例、
@echo off
setlocal enabledelayedexpansion
set var=^&
echo !var!
pause
这段代码运行结果是正确的。
（五）
既然都要处理符号，那么%%型和!!型的符号处理会不会是同一个过程？
（一）中的例子已经可以说明问题，不过我还有例子可以证明。
例、
@echo off
echo "^^^^^^^^"!!
setlocal enabledelayedexpansion
echo "^^^^^^^^"!!
pause
对于%%型，在符号处理时，不处理双引号间的脱字字符；而对于!!型
则相反。
三、call引出的一些问题
（一）
call与脱字字符
例、
@echo off
set /p var=<hero.txt
echo "%var%"
call echo "%var%"
pause
其中hero.txt中的内容为8个脱字字符：^^^^^^^^
结果是：
"^^^^^^^^"
"^^^^^^^^^^^^^^^^"
请按任意键继续. . .
结果是否有些出乎意料？我们知道，系统在预处理时不会处理双引号
间的脱字字符，那就意味着是call命令将其后的脱字字符数量加了倍
。看来call命令和脱字字符还真有点“暧昧”。
例、
@echo off
set /p var=<hero.txt
echo %var%
call echo %var%
pause
本例中变量var的值为8个“^”，运行“call echo %var%”时，首先
进行变量替换把%var%替换为^^^^^^^^，再经一次符号的处理变为^^^^
，此时由于call命令使得脱字字符数目增加一倍变为8个，然后再进行
call本身的预处理，这样结果就为4个“^”。
这样就能解释下面的代码为什么会显示4个“^”。
@echo off
call call call call echo ^^^^^^^^
pause
（二）
call与其它特殊字符
这里所说的“其它特殊字符”主要指&、>、|等。
这里请允许我自定义两个名词：
主预处理过程：系统本身预处理过程的总称，其中包括了%%型和!!型
。
次预处理过程：由于call命令引起的预处理过程的总称。
“其它特殊字符”是在主预处理过程中被系统识别的，而在次预处理
过程中对这些符号的识别是有问题的。
例、
@echo off
call echo hero!^&pause
pause
本例中，经过主预处理过程，&被识别为普通字符，而在次预处理过程
中符号&的识别将产生问题。正如《命令行参考》中提到的--不要在
call 命令中使用管道和重定向符号。（这倒不是说call语句中不能使
用那些符号，而是这些符号不能作为参数传递给call命令。）
这也从某种程度上说明某行语句的句子结构（一条还是多条）和功能
（是从定向输出还是其它）是在主预处理过程中确定的。
以上所有内容，只是我个人的看法，由于没有官方文档的支持，因
此仅供参考。
那么我们学了以上种种内容又有什么实际用途呢？我想，懂得了以上
道理就可以写出更加个性化的代码，同时也可以作为一种伪装术在实
际中应用。
@echo off
set ^&=setlocal enabledelayedexpansion
set ^^^^^hero=^^^^^&p
set ^au=^^^au
set ^^^^^^^^^=障眼法
%&%
set ^^^^^se=^^^se!
echo %^^^^%!%^^hero%!au%^se%
作者: plp626 时间: 2008-5-12 10:26
真不错，能继续讲下去就好了。。。
还有关于for /f
复合句的，等等。。。