标题: 为什么在if中被比较的变量不加引号就不能直接截取呢？ [打印本页]
作者: Hanyeguxing 时间: 2009-9-19 06:35 标题: 为什么在if中被比较的变量不加引号就不能直接截取呢？
1，有这样一个变量，他是由数字构成，前面为若干个0，去掉这些0，我可以用这样的方法：批处理1
@echo off&setlocal enabledelayedexpansion
set E=000001
call :D !E!
echo 结果!E!
pause&exit
:D
set E=%1
:F
if "!E:~0,1!" == "0" set E=!E:~1!&goto F
2，因为这里使用了call和两个标签，我想换一个方法，通过00=0来判断。set E=000001
call :D !E!
echo 结果!E!
pause&exit
:D
set E=%1
:F
if "!E:~0,1!" == "0" set E=!E:~1!&goto F
测试：批处理2
@echo off
set a=000
if "%a%" == "00" (echo 等于1) else echo 不等1
if "%a%" == 00 (echo 等于2) else echo 不等2
if %a% == 00 (echo 等于3) else echo 不等3
if "%a%" equ "00" (echo 等于4) else echo 不等4
if "%a%" equ 00 (echo 等于5) else echo 不等5
if %a% equ 00 (echo 等于6) else echo 不等6
pause
运行结果：set a=000
if "%a%" == "00" (echo 等于1) else echo 不等1
if "%a%" == 00 (echo 等于2) else echo 不等2
if %a% == 00 (echo 等于3) else echo 不等3
if "%a%" equ "00" (echo 等于4) else echo 不等4
if "%a%" equ 00 (echo 等于5) else echo 不等5
if %a% equ 00 (echo 等于6) else echo 不等6
pause
不等1
不等2
不等3
不等4
不等5
等于6
所以，使用 equ 及不使用引号，就可以实现比较时000等于0。
3，于是，做了一个这样的批处理：批处理3
@echo off&setlocal enabledelayedexpansion
set E=000001
for /l %%k in (5 -1 1) do if !E:~0,%%k! equ 0 set E=!E:~%%k!
echo 结果!E!
pause
出现错误：此时不应有 %k!。set E=000001
for /l %%k in (5 -1 1) do if !E:~0,%%k! equ 0 set E=!E:~%%k!
echo 结果!E!
pause
只能写成这样才可以：批处理4
@echo off&setlocal enabledelayedexpansion
set E=000001
for /l %%k in (5 -1 1) do if "!E:~0,%%k!" equ "00000" set E=!E:~%%k!
echo 结果!E!
pause
运行正常set E=000001
for /l %%k in (5 -1 1) do if "!E:~0,%%k!" equ "00000" set E=!E:~%%k!
echo 结果!E!
pause
或者是：批处理5
@echo off&setlocal enabledelayedexpansion
set E=000001
for /l %%k in (5 -1 1) do set F=!E:~0,%%k!&if !F! equ 0 set E=!E:~%%k!
echo 结果!E!
pause
运行正常set E=000001
for /l %%k in (5 -1 1) do set F=!E:~0,%%k!&if !F! equ 0 set E=!E:~%%k!
echo 结果!E!
pause
为什么在这里(批处理3)，不使用引号就不能直接截取!E:~0,%%k!呢？
[ Last edited by Hanyeguxing on 2009-9-19 at 06:57 ]
作者: wxcute 时间: 2009-9-19 11:16 标题: F话不多说，自己研究更有成就。
在逗号前加个转义符，变成：^,
作者: everest79 时间: 2009-9-20 09:05
if 不支持变量二次扩展
作者: q8249014 时间: 2009-9-20 09:05
2f说的是对的，可是没有说明原因
先请楼主运行以下代码
if 1, equ 1 echo ok
pause>nul
pause>nul
if 1 equ 1 echo ok
pause>nul
可见以上两段代码执行的结果都是一样的pause>nul
代码中没有用"echo off" 楼主可以把cmd屏幕中的命令行和以上代码比较一下
就会发现cmd在预处理的时候会把IF后需要比较字符中的某些特殊字符过滤掉。
通过比较cmd屏幕回显中的命令可以发现实际上连段代码执行的都是
"if 1 EQU 1 echo ok"
所以上面两段代码的执行结果才会一样
在你的代码中 加上"^"就把","转义为普通字符 所以
就成功啦
类似的字符还有";" 还有什么特殊字符lz有兴趣自己找一下 o(∩_∩)o...
那么lz的代码就应该变为以下代码
@echo off&setlocal enabledelayedexpansion
set E=000001
for /l %%k in (5 -1 1) do if !E:~0^,%%k! equ 0 set E=!E:~%%k!
echo 结果!E!
pause
或者可以这样理解set E=000001
for /l %%k in (5 -1 1) do if !E:~0^,%%k! equ 0 set E=!E:~%%k!
echo 结果!E!
pause
我们知道","在批处理中起分隔符的作用
那么 " if !E:~0^,%%k! equ 0 set E=!E:~%%k!"
就变成了 "if !E:~0 %%k! equ 0 set E=!E:~%%k!"
请执行
if !E:~0 %%k! equ 0 set E=!E:~%%k!
也就是说空格(分隔符)后面应该为比较运算符 而你却写成了 %%k! 它自然就报错了
if 1 1
if 1,geq,1,echo.ok
我想试完以上代码 你应该就明白了 o(∩_∩)o...[ Last edited by q8249014 on 2009-9-20 at 11:10 ]
作者: everest79 时间: 2009-9-20 13:52
.....
if %a:~0^,1% equ 1 echo ok
if %a:~0,1% equ 1 echo ok
自已测试下
作者: Hanyeguxing 时间: 2009-9-21 04:08
set "a b=123"
set "a,b=123"
set a=123
if %a b% equ 123 echo 相等1
if %a,b% equ 123 echo 相等2
if %a:~0,1% equ 1 echo 相等3
setlocal enabledelayedexpansion
if %a b% equ 123 echo 相等4
if %a,b% equ 123 echo 相等5
if !a^ b! equ 123 echo 相等6
if !a^,b! equ 123 echo 相等7
if %a:~0,1% equ 1 echo 相等8
if !a:~0^,1! equ 1 echo 相等9
pause
为什么只有!!内才需要这样，%%内就不需要。。。。。。set "a,b=123"
set a=123
if %a b% equ 123 echo 相等1
if %a,b% equ 123 echo 相等2
if %a:~0,1% equ 1 echo 相等3
setlocal enabledelayedexpansion
if %a b% equ 123 echo 相等4
if %a,b% equ 123 echo 相等5
if !a^ b! equ 123 echo 相等6
if !a^,b! equ 123 echo 相等7
if %a:~0,1% equ 1 echo 相等8
if !a:~0^,1! equ 1 echo 相等9
pause
作者: plp626 时间: 2009-9-21 04:09
预处理时，,;=空格(共四个)被作为参数分隔符了，
作者: everest79 时间: 2009-9-21 04:14
| Quote: | |
|
这样
作者: q8249014 时间: 2009-9-21 06:27
回6f:
@set a=123
if %a:~0,1% equ 1 echo 相等8
@pause>nul
运行以上代码 看CMD屏幕中的代码 可以发现 执行的是if %a:~0,1% equ 1 echo 相等8
@pause>nul
"if 1 EQU 1 echo 相等8"
其实还是CMD预处理的问题 %%的优先级比!!高 在预处理时(命令执行之前)
%a:~0,1%就被替换为1了 所以不会出错
关于这个"优先级"的问题 以前 bjsh版主讨论过这个问题
以下是bjsh版主写的那篇帖子
http://www.cn-dos.net/forum/viewthread.php?tid=30884&fpage=1&highlight=%2Bbjsh