标题: 【已解决】for 获取 reg query命令结果的语法问题求助 [打印本页]
作者: 904055262 时间: 2009-9-15 02:55 标题: 【已解决】for 获取 reg query命令结果的语法问题求助
for /f %%a in ('reg query "HKCU\software\microsoft\windows\currentversion\explorer\shell folders" /v "desktop" ') do (
echo.%%a
)
红色部分 单独执行能得到正确的结果 但是在FOR里面执行 会得到：HKCU\software\microsoft\windows\currentversion\explorer\shell
[ Last edited by 904055262 on 2009-9-15 at 06:29 ]
作者: Hanyeguxing 时间: 2009-9-15 04:18
在不启用usebackq的时候，需要加上"delims="
说明：不使用任何关键字的时候，所有的for /f都是以空格做为默认分隔符的，包括对 in ('command') 中的 ""英文引号括起来的部分
set a=reg query "HKCU\software\microsoft\windows\currentversion\explorer\shell folders" /v "desktop"
for /f "skip=4 delims=" %%i in ('%a%') do for /f "tokens=2,*" %%j in ("%%i") do echo %%k
或者for /f "skip=4 delims=" %%i in ('%a%') do for /f "tokens=2,*" %%j in ("%%i") do echo %%k
set a=reg query "HKCU\software\microsoft\windows\currentversion\explorer\shell folders"
for /f "delims=" %%i in ('%a% ^| FIND /I "desktop"') do for /f "tokens=2,*" %%j in ("%%i") do echo %%k
如果觉得for /f次数过多，可以启用usebackq，例如：for /f "delims=" %%i in ('%a% ^| FIND /I "desktop"') do for /f "tokens=2,*" %%j in ("%%i") do echo %%k
for /f "usebackq skip=4 tokens=2,*" %%i in (`reg query "HKCU\software\microsoft\windows\currentversion\explorer\shell folders" /v "desktop"`) do echo %%j
或者for /f "usebackq tokens=2,*" %%i in (`reg query "HKCU\software\microsoft\windows\currentversion\explorer\shell folders" ^| FIND /I "desktop"`) do echo %%j
说明：usebackq就是用来处理 for /f 中字符串中的空格的[ Last edited by Hanyeguxing on 2009-9-15 at 06:45 ]
作者: Hanyeguxing 时间: 2009-9-15 05:57
补充说明：
1，因为批处理1和2使用了2次for，而批处理3和4只使用了1次，所以一般推荐使用批处理3和4。
2，批处理1和2的 in ('command') 中使用了英文双引号"和英文单引号'
批处理3和4的 in ('command') 中使用了英文双引号"和英文后引号`
要注意区别英文单引号和后引号
3，如果要显示整行内容，可以将tokens=2,*改成tokens=*，并将echo 后的变量前移一个字母顺序，例如在批处理3和4把echo %%j改成echo %%i，在批处理1和2把echo %%k改成echo %%j。
4，在不考虑 desktop 存在重复出现的可能，则这些批处理都可以用。如果需要考虑 desktop 存在重复（例如帐户名或目录路径名中或目录名本身包含 desktop）的可能，则推荐使用批处理1和3。
[ Last edited by Hanyeguxing on 2009-9-15 at 06:10 ]
作者: 904055262 时间: 2009-9-15 06:27
这样就可以了 我自己弄错了 我晕 不过谢谢你
for /f "tokens=2*" %%a in ('reg query "HKCU\software\microsoft\windows\currentversion\explorer\shell folders" /v "desktop" ^|findstr /i "desktop" ') do ( echo.%%b )
作者: 904055262 时间: 2009-9-15 06:29
你答的真用心 学到新东西了 感谢。。