标题: 关于FOR取值的一个疑问
[打印本页]
作者: THENEWLIFE
时间: 2009-4-4 10:06
标题: 关于FOR取值的一个疑问
IPD这个变量是192.168.0.8
for %%a in (%ipd:.= %) do set IPD4=%%a
这句为什么会是把8提出来呢，因该是显示 192 168 0 8 才对啊
难道是因为IPD后面加了个4的原因所以才取第4位吗
个人感觉因该像这个例子样
for %a in (aa.txt bb.txt cc.txt) do @echo %a
输出
aa.txt
bb.txt
cc.txt
我又回去看了几遍关于FOR的介绍，还是不明白，还请大大详细说明下
作者: wjcing
时间: 2009-4-4 16:43
@echo off
setlocal enabledelayedexpansion
set ipd=192.168.0.8
set /a _T=0
for %%a in (%ipd:.= %) do (
set /a _T+=1
set IPD!_T!=%%a
)
echo !IPD1! !IPD2! !IPD3! !IPD4!
ENDLOCAL
pause
作者: netbenton
时间: 2009-4-4 20:25
因为for 的作用，后面的set ipd4=%%a执行了4次，前面的3次是临时的，
最后就得到了第4次的结果了。
作者: Pierre
时间: 2009-4-4 22:40
F:\>for %a in (%ipd:.= %) do @echo %a
192
168
0
8
当set的时候，其实是进行了4次set，最后一次的值留了下来
作者: THENEWLIFE
时间: 2009-4-4 23:52
楼的方法是通过SET /A 递增的效果让我看的更清楚吧，
@echo off
setlocal enabledelayedexpansion
set ipd=192.168.0.8
set /a _T=0
for %%a in (%ipd:.= %) do (
set /a _T+=1
set IPD!_T!=%%a
)
echo !IPD1! !IPD2! !IPD3! !IPD4!
ENDLOCAL
pause
它能一个一个显示出来是因为开启了变量延迟吗
作者: wjcing
时间: 2009-4-5 01:03
@echo off
setlocal enabledelayedexpansion
set ipd=192.168.0.8
set /a _T=0
for %%a in (%ipd:.= %) do (
set /a _T+=1
set IPD!_T!=%%a
call echo 变量延迟:%%IPD!_T!%%
echo 变量未延迟:%_T%
)
echo %IPD1% %IPD2% %IPD3% %IPD4%
ENDLOCAL
pause
不是...如果在for体内引用才用变量延迟..
作者: THENEWLIFE
时间: 2009-4-5 12:25
for %%a in (%ipd:.= %) do set IPD4=%%a
for %%a in (%ipd:.= %)如果不加后面的就因该会产生4个变量 %%a %%b %%c %%d 他们分别是%%a=192 %%b=168 %%c=0 %%d=8
所以你直接定义IPD4=%%a 就可以省略了这句“set /a _T+=1
set IPD!_T!=%%a 是吗
不知道我理解的对不对
作者: HAT
时间: 2009-4-6 02:05
标题: Re 7楼
你理解的不对
在回头看看别人的回复吧
作者: balinger
时间: 2009-4-6 03:23
Originally posted by THENEWLIFE at 2009-4-5 12:25 PM:
for %%a in (%ipd:.= %) do set IPD4=%%a
for %%a in (%ipd:.= %)如果不加后面的就因该会产生4个变量 %%a %%b %%c %%d 他们分别是%%a=192 %%b=168 %%c=0 %%d=8
所以你直接定义IPD ...
@echo off
set ipd=192.168.0.8
for /f "usebackq tokens=1-4" %%a in ('%ipd:.= %') do (
echo %%a
echo %%b
echo %%c
echo %%d)
pause
exit
@echo off
set ipd=192.168.0.8
for /f "tokens=1-4" %%a in ('echo %ipd:.= %') do (
echo %%a
echo %%b
echo %%c
echo %%d)
pause
exit
作者: THENEWLIFE
时间: 2009-4-6 08:13
Originally posted by netbenton at 2009-4-4 08:25 PM:
因为for 的作用，后面的set ipd4=%%a执行了4次，前面的3次是临时的，
最后就得到了第4次的结果了。
又回去看了几遍，是不是这个意思：
因为FOR每次都以一个变量来定义IPD4，比如第一次是用192.第二次就变成了168，所以就这样替换下去就变成了8 ，
这样理解因该是对的吧<img src="images/smilies/face-raspberry.png" align="absmiddle" border="0">
作者: balinger
时间: 2009-4-6 09:14
楼主理解对了
FOR循环执行do后(...)内的操作,循环几次,看in后( )内有几个可替换的参数
每次do操作,变量都取一个参数值
for %%a in (192 168 0 8) do (...) 表示有4个参数，默认以空格分割参数,变量%%a
第一次用第一个参数,赋值与变量,%%a=192
第二次用第二个参数,赋值与变量,%%a=168
......
当然,可替换参数的来源还有其它情形
作者: THENEWLIFE
时间: 2009-4-6 09:18
谢谢大家的指导