标题: 如何将多行数据变成一行？ [打印本页]
作者: shelby 时间: 2009-1-22 14:30 标题: 如何将多行数据变成一行？
数据如下：
DESCRIPTION SUM(ENTRY021)
-------------------- -------------
东莞东 73700
广州 225071
广州东 122342
深圳 105813
深圳西 40930
已选择5行。
希望得出如下的结果：
东莞东73700，广州东225071，深圳105813，深圳西40930。
作者: lihan584 时间: 2009-1-22 15:46
::ywj.txt是原文件，bcwj.txt是将要保存的文件
@echo off
FOR /F "tokens=1,2 delims= " %%a in (ywj.txt) do set /p jg=%%a%%b,<nul>>bcwj.txt
pause
作者: shelby 时间: 2009-1-22 16:45
非常感谢！我知道前2行可以通过 skip=3 来去掉。但是还有点小问题就是最后一行的数据（已选择5行。）如何去掉？
作者: yishanju 时间: 2009-1-22 17:46
用type xxx.txt |findstr /rc:"[0-9]*" 过滤一次
作者: tireless 时间: 2009-1-22 17:57
@echo off
for /f "skip=3 tokens=1,2" %%a in (a.txt) do (
set /a "n+=1,1/(5-n)" 2>nul || echo %%a%%b。>>a_new.txt && exit /b
set /p =%%a%%b，<nul>>a_new.txt
)
for /f "skip=3 tokens=1,2" %%a in (a.txt) do (
set /a "n+=1,1/(5-n)" 2>nul || echo %%a%%b。>>a_new.txt && exit /b
set /p =%%a%%b，<nul>>a_new.txt
)
作者: shelby 时间: 2009-1-22 18:09
楼上的强！do里面的命令好多看不懂，能够解释一下？呵呵。。另外，这些都是在循环里面控制输出的，能否将结果放在一个变量中，然后在循环外引用？
作者: tireless 时间: 2009-1-22 18:55 标题: Re 6楼
set /a n+=1 变量 n 的数值加 1
set /a 1/(5-n) 为了判断行数。当除数为零时导致出错，然后就会执行 || 后的命令。 (参考: CMD/DOS下符号的作用参考)
2>nul “标准错误输出”输出到空设备 (参考: 重定向中的秘密)
set /p =%%a%%b，<nul>>a_new.txt 以空设备作为输入源，代替了从键盘输入，从而语句结束。因为没有输入回车符，所以不会换行。
------------------
将结果放到变量中：
@echo off
setlocal enabledelayedexpansion
for /f "skip=3 tokens=1,2" %%a in (a.txt) do (
set /a n+=1
if !n!==5 set "str=!str!%%a%%b。" & goto Next
set "str=!str!%%a%%b，"
)
:Next
echo %str%
pause
[ Last edited by tireless on 2009-1-22 at 19:43 ]setlocal enabledelayedexpansion
for /f "skip=3 tokens=1,2" %%a in (a.txt) do (
set /a n+=1
if !n!==5 set "str=!str!%%a%%b。" & goto Next
set "str=!str!%%a%%b，"
)
:Next
echo %str%
pause
作者: netbenton 时间: 2009-1-23 00:24 标题: 在2楼上增强就可以了
@echo off
FOR /F "tokens=1,2 delims= " %%a in (ywj.txt) do if "%%a"=="已选择5行。" exit&set /p jg=%%a%%b,<nul>>bcwj.txt
pause