Board logo

标题: [已结]如何获得当前日期的星期值? [打印本页]

作者: ruisoft     时间: 2008-11-29 11:20    标题: [已结]如何获得当前日期的星期值?
我的系统是 WINXP,%DATE% 中只有日期值 2008-11-29

没有星期值!

论坛中相关帖子是用VBS脚本写的。

有不有不用VBS脚本就可以获得当前日期的星期值?

Last edited by HAT on 2008-12-1 at 18:05 ]

作者: HAT     时间: 2008-11-29 12:01
echo %date%
结果贴出来看看
@echo off
call :DateToDOW %date:~0,4% %date:~5,2% %date:~8,2% dow
echo 星期%dow%
goto :eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:DateToDOW %yy% %mm% %dd% dow
::
:: By: Ritchie Lawrence, 2003-04-29. Version 1.1
::
:: Func: Creates a day of week number from a calendar date, where 1 = Mon
:: and 7 = Sun. For NT4/2000/XP/2003.
::
:: Args: %1 year component to be converted, 2 or 4 digits (by val)
:: %2 month component to be converted, leading zero ok (by val)
:: %3 day of month to be converted, leading zero ok (by val)
:: %4 var to receive day of week number, 1 to 7 (by ref)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1
endlocal&set %4=%dow%&goto :EOF
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


Last edited by HAT on 2008-11-29 at 12:10 ]

作者: ruisoft     时间: 2008-11-29 13:30
set /a dd=100%dd%%%100,mm=100%mm%%%100

这句没看懂。

这里,%的作用是什么?

求余数?

作者: HAT     时间: 2008-11-29 13:33    标题: Re 3楼
你的理解很正确

作者: HAT     时间: 2008-11-29 13:50
@echo off
>"%temp%\myWeek.vbs" echo wscript.echo WeekdayName(Weekday(CDate(Now)))
for /f %%a in ('cscript /nologo "%temp%\myWeek.vbs"') do (
set weekDay=%%a
)
echo %weekDay%
pause

作者: ruisoft     时间: 2008-11-29 13:59
后两句中

“/=”运算符是何种运算?

4800指示什么意义?
153又指什么意义?
2472630又指什么意义?

set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1

作者: HAT     时间: 2008-11-29 14:03    标题: Re 6楼
/=是整除的一种写法
set /a num=num/2
相当于
set /a num/=2

那些数字是根据数学公式推导出来的,Ritchie Lawrence 的批处理函数库中很多类似的东西,如果对此类算法感兴趣,可google之。

作者: abcd     时间: 2008-11-29 14:17
啊,完全看不懂啊,各们高手

作者: ruisoft     时间: 2008-12-1 17:50
OK! 谢谢啦!

作者: aroma281     时间: 2010-12-3 12:08
原來如此!!!又學到了東西3Q