Board logo

标题: [求教]call变量延迟的疑惑 [打印本页]

作者: moniuming     时间: 2008-9-13 13:27    标题: [求教]call变量延迟的疑惑
当用下面的代码时,无法取得余数,会显示随机数及除数的后两位数字,如图:
@echo off
:agn
for /l %%a in (0 1 9) do (
call set /a "dos=%%random%%%%234"
call echo %%dos%%
)
pause&cls&goto :agn




用下面的代码才能正常显示
@echo off
setlocal enabledelayedexpansion
:bgn
for /l %%a in (0 1 9) do (
set /a "dos=!random!%%234"
call echo %%dos%%
)
pause&cls&goto :bgn


请各位指教

作者: HAT     时间: 2008-9-13 14:11
是不是这个意思?
@echo off
:agn
for /l %%a in (0 1 9) do (
call set /a "dos=%%random%%%%%%234"
call echo %%dos%%
)
pause&cls&goto :agn

作者: moniuming     时间: 2008-9-13 14:22
Originally posted by HAT at 2008-9-13 14:11:
是不是这个意思?
@echo off
:agn
for /l %%a in (0 1 9) do (
call set /a "dos=%%random%%%%%%234"
call echo %%dos%%
)
pause&cls&goto :agn

就是这个意思,非常感谢!!!

作者: DwD     时间: 2009-3-18 03:13
楼上的两位都明白了,打哑谜在。
能不能把明白的都说出来啊
没想到延迟变量和逃逸字符%还有这么多内容。
一时难以理解

作者: moniuming     时间: 2009-3-18 04:35
Originally posted by DwD at 2009-3-18 03:13:
楼上的两位都明白了,打哑谜在。
能不能把明白的都说出来啊
没想到延迟变量和逃逸字符%还有这么多内容。
一时难以理解

我来解释一下吧,如有不妥,请指正
把%号分开些会容易些:
@echo off
:agn
for /l %%a in (0 1 9) do (
call set /a "dos=%%random%% %%%%234"
call echo %%dos%%
)
pause&cls&goto :agn

set /a 变量=数字%%数字
是取余运算,详情请:set /?
%random%是随机数
call的机制如下:
call一次,会把百分号脱掉一半,例中:
call set /a "dos=%%random%% %%%%234"
call后会变成set /a "dos=%random% %%234"
随后再运行%random% %%234,把值赋给dos
下一句同理...
举一例:

@echo off
set a=verdana
set b=%a%
set c=%b%
set d=%c%
call call call echo.%%%%%%%%d%%%%%%%%
pause

作者: DwD     时间: 2009-3-18 23:40
%% %% %% %%d%% %% %% %%
CALL 第一次成了 % % % % d % % % %
call 第二次成了 % % d % %
第三次 % d %
echo %d% 就是echo %a%
为什么要弄那么多%%%%%%%,就是因为使它成为动态变量,在被转义的时候不被转义成字符串常量。
学习了,我对call ,%,延迟变量又理解了深入点。
谢谢楼上两位。

作者: mmh1     时间: 2009-3-19 00:54
@echo off
set a=verdana
set b=%a%
set c=%b%
set d=%c%
call call call echo.%%%%%%%%d%%%%%%%%
pause
怎么没有达到预计的结果啊
本来显示的应该是verdana吧,结果。。。。。不停处理,然后过一会就没了
用call echo.%%d%%倒是可以用,用了第二个call怎么就不行了呢

作者: DwD     时间: 2009-3-19 00:59
我又试了次,我的一点问题没有。

作者: mmh1     时间: 2009-3-19 02:43
找到结果了,我把名字改为call.bat,结果一运行就不停了~~~~~~