标题: 如何得到下一级目录的包含文件数量？ [打印本页]
作者: ak30000 时间: 2008-8-25 13:22 标题: 如何得到下一级目录的包含文件数量？
想要做这样的事情：
罗列当前目录的下一级子目录，并且能得到每个当前目录的下一级子目录包涵的文件数
先谢谢了
作者: HAT 时间: 2008-8-25 13:34
CODE: [Copy to clipboard]@echo off
for /f "tokens=*" %%a in ('dir /b /ad') do (
for /f "tokens=*" %%b in ('dir /s /b /a-d "%%a" 2^>nul') do (
set /a Folder_%%a+=1
)
)
set Folder_
作者: ak30000 时间: 2008-8-25 13:53 标题: 我是新手，还有个实际应用问题
谢谢楼上的，假如我要的是每个当前目录的下一级子目录包涵的文件夹数，以及每个当前目录的下一级子目录的大小可以么？
谢谢，万分
作者: HAT 时间: 2008-8-25 14:18
CODE: [Copy to clipboard]@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%a in ('dir /b /ad') do (
for /f "tokens=*" %%b in ('dir /s /b /a-d "%%a" 2^>nul') do (
set /a File_in_%%a+=1
set /a n+=%%~zb
)
echo 文件夹%%a中共有文件大小为!n!字节
set "n=0"
for /f "tokens=*" %%b in ('dir /s /b /ad "%%a" 2^>nul') do (
set /a Folder_in_%%a+=1
)
)
echo.
echo 每个当前目录的下一级子目录包涵的文件数
set File_in_
echo.
echo 每个当前目录的下一级子目录包涵的文件夹数
set Folder_in_
echo.
pause
作者: ak30000 时间: 2008-8-25 14:26
谢谢，实际我要完成的功能也就是在某个目录的任意一个子目录上右健属性看到的该目录包含文件数量，文件夹数量，以及大小
不过我要一次性得到当前目录下很多目录的同一属性。这样手动就很麻烦，特别是当前目录有上百个子目录，而每一个子目录又有上百万个文件和子目录，要统计起来不求助高手，相信我是要活活累死的。
真是万分感谢！
另外我可以假如qq群么？开始对这一块感兴趣了
作者: ak30000 时间: 2008-8-25 14:43
还有个问题
echo 文件夹%%a中共有文件大小为!n!字节
set "n=0"
这两句，前一句执行完以后报一个错
'iiset' is not recognized as an internal or external command
并且多个同级子目录的大小确是累加的,也就是到第三个目录，现实的是前三个目录的综合大小这样子
作者: HAT 时间: 2008-8-25 16:05
问题1：加个双引号试试
CODE: [Copy to clipboard]如果问题依旧，请给出包含'iiset'的文件夹的全名。@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%a in ('dir /b /ad') do (
set "n=0"
for /f "tokens=*" %%b in ('dir /s /b /a-d "%%a" 2^>nul') do (
set /a File_in_%%a+=1
set /a n+=%%~zb
)
echo 文件夹"%%a"中共有文件大小为!n!字节
for /f "tokens=*" %%b in ('dir /s /b /ad "%%a" 2^>nul') do (
set /a Folder_in_%%a+=1
)
)
echo.
echo 每个当前目录的下一级子目录包涵的文件数
set File_in_
echo.
echo 每个当前目录的下一级子目录包涵的文件夹数
set Folder_in_
echo.
pause
问题2：上面的代码修改了变量初始化的位置，再试试吧。
作者: hhzjxss 时间: 2010-8-20 23:06
谢谢，下载收藏了！