标题: 这个批处理错在哪里了？ [打印本页]

---

作者: shayulei     时间: 2008-8-7 15:55    标题: 这个批处理错在哪里了？

@echo on
for /f "Tokens=1-3" %%i in ('diskpart /s z:\diskpart\Testc.txt ^| find "*" ') do set /a SystemPart=%%k
if %SystemPart% gtr 0 (       
          if %systemPart% lss 20 (
                ::生成boot.ini
                echo [boot loader] > d:\boot.ini
                echo timeout=30 >> d:\boot.ini
                echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\boot.ini
                echo [operating systems] >> d:\boot.ini
                echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect /detecthal >> d:\boot.ini
                ::生成bootxp.ini
                echo [boot loader] > d:\bootxp.ini
                echo timeout=30 >> d:\bootxp.ini
                echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\bootxp.ini
                echo [operating systems] >> d:\bootxp.ini
                echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect >> d:\bootxp.ini
        )else (echo 测试系统盘出错，请手处理boot.ini & goto :EOF)
)
:end

运行到echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\boot.ini
就报 “不应有disk(0“
是什么意思，如果我把IF去掉，这个批处理就没有问题。

---

作者: knoppix7     时间: 2008-8-7 15:56
括号内注释不能用::
要用REM

---

作者: shayulei     时间: 2008-8-7 16:00
神奇啊，我双击运行这个批处理就不会报错，我在命令行窗口中运行，他就报错，怎么回事？

---

作者: HAT     时间: 2008-8-7 16:02
你在最后添加一行
pause
双击运行也不报错？

---

作者: shayulei     时间: 2008-8-7 16:10
我把注释删了，还是报错
Z:\>createboot

Z:\>for /F "Tokens=1-3" %i in ('diskpart /s z:\diskpart\Testc.txt | find "*" ')
do set /a SystemPart=%k

Z:\>set /a SystemPart=1
此时不应有 disk(0。

Z:\>            echo default=multi(0)disk(0)rdisk(0)partition(1)\WINDOWS >> d:\b
oot.ini

Z:\>

---

作者: shayulei     时间: 2008-8-7 16:20
是（）的问题，现在改成这样了
@echo off

attrib -h -s -r c:\boot.ini
attrib -h -s -r c:\bootxp.ini

for /f "Tokens=1-3" %%i in ('diskpart /s z:\diskpart\Testc.txt ^| find "*" ') do set /a SystemPart=%%k
if %SystemPart% LSS 1 GOTO error
if %systemPart% GTR 10 goto error

::生成boot.ini
echo [boot loader] > d:\boot.ini
echo timeout=30 >> d:\boot.ini
echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\boot.ini
echo [operating systems] >> d:\boot.ini
echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect /detecthal >> d:\boot.ini

::生成bootxp.ini
echo [boot loader] > d:\bootxp.ini
echo timeout=30 >> d:\bootxp.ini
echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\bootxp.ini
echo [operating systems] >> d:\bootxp.ini
echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect >> d:\bootxp.ini

goto :EOF
:error
echo 测试系统盘出错，请手处理boot.ini & goto :EOF

:end