标题: 10进制转16进制： [打印本页]
作者: bat-zw 时间: 2008-7-5 13:19 标题: 10进制转16进制：
@echo off
set code=0123456789abcdef
:enter
cls&set /p num=请输入一个十进制数字：
echo %num%|findstr "[^0-9]"&&goto enter
set var=%num%
:again
set /a ws=%var%%%16
call,set ws=%%code:~%ws%,1%%
set /a var/=16
set str=%ws%%str%
if %var% geq 16 goto again
cls&echo 十进制数%num%转换为16进制数为：%var%%str%
pause>nul
[ Last edited by zw19750516 on 2008-7-5 at 01:50 PM ]set code=0123456789abcdef
:enter
cls&set /p num=请输入一个十进制数字：
echo %num%|findstr "[^0-9]"&&goto enter
set var=%num%
:again
set /a ws=%var%%%16
call,set ws=%%code:~%ws%,1%%
set /a var/=16
set str=%ws%%str%
if %var% geq 16 goto again
cls&echo 十进制数%num%转换为16进制数为：%var%%str%
pause>nul
作者: HAT 时间: 2008-7-5 13:39
以前看别人写的
@echo off
rem 最大处理数字是2147483647
setlocal ENABLEDELAYEDEXPANSION
set /p num=num?
set str=0123456789ABCDEF
call :A %num%
echo %T3%
echo %num%
pause
exit
:A
set T1=%1
SET T3=
:B
set/A T2=T1%%16
SET T2=!str:~%t2%,1!
SET/A T1=%T1%/16
SET T3=%T2%%T3%
IF %T1%==0 GOTO :EOF
GOTO B
rem 最大处理数字是2147483647
setlocal ENABLEDELAYEDEXPANSION
set /p num=num?
set str=0123456789ABCDEF
call :A %num%
echo %T3%
echo %num%
pause
exit
:A
set T1=%1
SET T3=
:B
set/A T2=T1%%16
SET T2=!str:~%t2%,1!
SET/A T1=%T1%/16
SET T3=%T2%%T3%
IF %T1%==0 GOTO :EOF
GOTO B
作者: pusofalse 时间: 2008-7-5 14:04
| Quote: | |
|
Sorry。。。是我肤浅。。。
[ Last edited by pusofalse on 2008-7-5 at 02:17 PM ]
作者: hackerscans 时间: 2008-7-5 14:19
强烈的向楼上各位学习。
作者: bat-zw 时间: 2008-7-5 14:23 标题: 16进制转10进制：
@echo off
set code=1 2 3 4 5 6 7 8 9 a b c d e f&set m=1
set /p str=请输入16进制数字：
:lp
set a=%str:~-1%
for %%i in (%code%) do set /a n+=1&if "%%i" equ "%a%" call,set a=%%n%%
set /a num+=m*a
set /a m*=16,n=0
if defined str set str=%str:~,-1%&goto lp
echo %num%&pause>nul
[ Last edited by zw19750516 on 2008-7-5 at 02:25 PM ]set code=1 2 3 4 5 6 7 8 9 a b c d e f&set m=1
set /p str=请输入16进制数字：
:lp
set a=%str:~-1%
for %%i in (%code%) do set /a n+=1&if "%%i" equ "%a%" call,set a=%%n%%
set /a num+=m*a
set /a m*=16,n=0
if defined str set str=%str:~,-1%&goto lp
echo %num%&pause>nul
作者: 26933062 时间: 2008-7-5 14:42
16进制转10进制：有更简单的方法。
@echo off
set /p b=请输入16进制数字：
set /a a=0x%b%
echo %a%
pause
set /p b=请输入16进制数字：
set /a a=0x%b%
echo %a%
pause
作者: pusofalse 时间: 2008-7-5 14:45 标题: hexadecimal2decimal
16进制转10进制，我知道一个再简单不过的方法，是昨天看到那篇获取asscii码的帖子知道的...
set/p num=
set/a a=0x%num%
echo %a%
pause
作者: bat-zw 时间: 2008-7-5 15:07
| Quote: | |
|
我才知道有这么简单，看来学习真无止境啊。
作者: HAT 时间: 2008-7-5 15:58
rem 三种不同的数据输入，但输出时都会使用十进制。
rem 十进制
set /a 123
rem 八进制
set /a 012
rem 十六进制
set /a 0xa
作者: zh159 时间: 2008-7-6 00:03
进制转换其实以前都有讨论过
作者: terse 时间: 2008-7-6 17:02
好象以前发过一个
加个变量 就可以实现十进制转任意进制
作者: HAT 时间: 2008-7-6 19:25
| Quote: | |
|
当时的代码
@echo off&setlocal enabledelayedexpansion
set/p a=请输入要转换的十进制数:
set aa=%a%
set/p b=请输入要转换的几进制?
set str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
:hex
set/a m=!a!/!b!
set/a n=!a!%%!b!
set n=!str:~%n%,1!
set h=!n!!h!
if !m! geq !b! set a=!m! &goto hex
set m=!str:~%m%,1!
echo !aa!的!b!进制数 !m!!h!
set/p a=请输入要转换的十进制数:
set aa=%a%
set/p b=请输入要转换的几进制?
set str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
:hex
set/a m=!a!/!b!
set/a n=!a!%%!b!
set n=!str:~%n%,1!
set h=!n!!h!
if !m! geq !b! set a=!m! &goto hex
set m=!str:~%m%,1!
echo !aa!的!b!进制数 !m!!h!
作者: ywwywwjm 时间: 2008-7-8 01:51
echo ibase=10;obase=16;10|bc
作者: HAT 时间: 2008-7-8 02:17
printf "%x" "10"
printf.exehttp://upload.cn-dos.net/img/580.zip