标题: [求助] 打开网页批处理，怎么修改下才好啊 [打印本页]
作者: kioskboy 时间: 2008-6-29 19:51 标题: [求助] 打开网页批处理，怎么修改下才好啊
@echo off
for /f "tokens=2*" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tencent Traveler" /v DisplayIcon^|findstr "DisplayIcon"') do set "tt=%%j"
IF ERRORLEVEL 1 goto ie
start "" "%tt%" www.baidu.com
start "" "%tt%" http://www.cn-dos.net/forum/
: ie
start iexplore http://www.baidu.com/
start iexplore http://www.cn-dos.net/forum/
exit
现在腾迅的TT换了版本，在网吧用时，安装的都是新版，我不是怎么喜欢
怎么在没有安装TT的条件下，也就是搜索不到上面的注册表项Tencent Traveler
或者是说上面的脚本运行错误，还是tt值没有情况下，改用IE打开上面的网站
怎么改下啊
[ Last edited by kioskboy on 2008-6-29 at 07:53 PM ]
作者: HAT 时间: 2008-6-29 21:25
你不是已经写出来了吗？
作者: kioskboy 时间: 2008-6-29 21:42
那我怎么运行了没有反应呢
作者: HAT 时间: 2008-6-29 21:53
怀疑是%path%的问题
你把最后一行改成
pause
看看结果是什么地方报错
作者: kioskboy 时间: 2008-6-29 22:00
谢谢，多写了，我在前面也写了个exit
对了，怎么我都重新打开一个explorer,怎么才能避免
如果改成 if %tt%=null 怎么表达呢
IF ERRORLEVEL 1 还要不要 IF ERRORLEVEL 2 和3 等等
那个ERRORLEVE 后面跟的数字各表示什么呢
[ Last edited by kioskboy on 2008-6-30 at 01:08 PM ]
作者: HAT 时间: 2008-6-30 00:07
//对了，怎么我都重新打开一个explorer,怎么才能避免
//IF ERRORLEVEL 1 还要不要 IF ERRORLEVEL 2 和3 等等
理解能力有限，不知道你想表达什么意思。
//如果改成 if %tt%=null 怎么表达呢
if not defined tt goto :ie
作者: kioskboy 时间: 2008-6-30 13:12
也就是说最上面的批处理运行后，打开了个“我的电脑” （explorer）
那个ERRORLEVE 后面跟的数字各表示什么,
谁能举些例子说明，ERRORLEVE number在具体的环境中各表示什么
[ Last edited by kioskboy on 2008-6-30 at 01:19 PM ]
作者: HAT 时间: 2008-6-30 13:39
//也就是说最上面的批处理运行后，打开了个“我的电脑” （explorer）
你是不是把iexplorer写成explorer了？
//那个ERRORLEVE 后面跟的数字各表示什么,
//谁能举些例子说明，ERRORLEVE number在具体的环境中各表示什么
查看帮助
if /?
作者: kioskboy 时间: 2008-6-30 13:45
没有呀，你可以把1楼的脚本运行下看看呀
作者: HAT 时间: 2008-6-30 14:03
@echo off
for /f "tokens=2*" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tencent Traveler" /v DisplayIcon^|findstr "DisplayIcon"') do set "tt=%%j"
if not defined tt goto ie
start "" "%tt%" www.baidu.com
start "" "%tt%" http://www.cn-dos.net/forum/
: ie
start iexplore http://www.baidu.com/
start iexplore http://www.cn-dos.net/forum/
exit
作者: kioskboy 时间: 2008-6-30 14:12
能不能把下面的代码再简化下，如过有6个网站或者更多，怎么搞
这个是我每天要用的，只好麻烦大家下了，帮我简化下，重复的代码太多，谢谢
@cho off
set "baidu=www.baidu.com"
set "cn-dos=http://www.cn-dos.net/forum/"
for /f "tokens=2*" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tencent Traveler" /v DisplayIcon^|findstr "DisplayIcon"') do set "tt=%%j"
if not defined tt goto ie
start "" "%tt%" %baidu%
start "" "%tt%" %cn-dos%
: ie
start iexplore %baidu%
start iexplore %cn-dos%
exit
作者: HAT 时间: 2008-6-30 14:21
@echo off
set "baidu=www.baidu.com"
set "cn-dos=http://www.cn-dos.net/forum/"
for /f "tokens=2*" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tencent Traveler" /v DisplayIcon^|findstr "DisplayIcon"') do set "tt=%%j"
if not defined tt goto :ie
for %%a in (%baidu% %cn-dos%) do (
start "" "%tt%" %%a
)
:ie
for %%a in (%baidu% %cn-dos%) do (
start iexplore %%a
)
set "baidu=www.baidu.com"
set "cn-dos=http://www.cn-dos.net/forum/"
for /f "tokens=2*" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tencent Traveler" /v DisplayIcon^|findstr "DisplayIcon"') do set "tt=%%j"
if not defined tt goto :ie
for %%a in (%baidu% %cn-dos%) do (
start "" "%tt%" %%a
)
:ie
for %%a in (%baidu% %cn-dos%) do (
start iexplore %%a
)
作者: balinger 时间: 2008-6-30 16:08
借用12楼代码，修改一下。
只要添加变量（变量名以URL_开始），或删除变量就可以了。方便加减网站。
@echo off
set "URL_baidu=www.baidu.com"
set "URL_cn-dos=http://www.cn-dos.net/forum/"
for /f "tokens=2*" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tencent Traveler" /v DisplayIcon ^|findstr "DisplayIcon"') do set "tt=%%j"
if not defined tt goto :ie
for /f "tokens=1* delims==" %%i in ('set URL_') do (
start "" "%tt%" %%j
)
exit
:ie
for /f "tokens=1* delims==" %%i in ('set URL_') do (
start iexplore %%j
)
[ Last edited by balinger on 2008-6-30 at 04:15 PM ]
作者: 1162888568 时间: 2010-6-29 16:31
好晕啊大牛。。膜拜。。。