中国DOS联盟论坛 - Powered by Discuz! Board

标题: [求助]随机生成不重复的10组7位数字的组合 [打印本页]

作者: leman 时间: 2008-2-29 17:57 标题: [求助]随机生成不重复的10组7位数字的组合

随即生成 10组 7位数字的组合,并不会重复

并判断10对组合每位出现次数
例如随即生成
1234567
1234567

-------------
1出现2次 2出现2次......

─────────────────　版务记录　─────────────────
执行：HAT
操作：在帖子标题中增加搜索关键字
说明：原标题"高手帮我写个关于数字随即脚本!"不利于论坛搜索
─────────────────　版务记录　─────────────────

Last edited by HAT on 2008-11-10 at 14:25 ]

作者: knoppix7 时间: 2008-2-29 18:21

自己搜索.

作者: qdloverr 时间: 2008-3-1 12:38

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,10) do (
set aa=!RANDOM!!RANDOM!!RANDOM!!RANDOM!!RANDOM!!RANDOM!
set aa=!aa:~0,7!
echo !aa!)
pause

后面的。。。。等斑斑

Last edited by qdloverr on 2008-3-1 at 12:40 PM ]

作者: moniuming 时间: 2008-3-3 13:19

@echo off

setlocal enabledelayedexpansion

:begin

type nul>"%temp%\temp.txt"

for /l %%a in (1,1,10) do (

set aa=!random!!random!!random!!random!!random!!random!!random!

set ab=!aa:~0,7!

echo !ab!

set/p=!ab!<nul >>"%temp%\temp.txt"

)

echo.

for /f "delims=" %%i in ('type "%temp%\temp.txt"') do set ac=%%i

set ad=0123456789

for /l %%b in (0,1,9) do (

set ae=0

set af=!ad:~%%b,1!

call :aaa

)

echo.&pause&cls&goto begin

:aaa

for /l %%j in (0,1,69) do (

set ag=!ac:~%%j,1!

if !ag!==!af! set /a ae+=1

)

echo !af!已经出现!ae!次

goto :eof

Last edited by moniuming on 2008-4-12 at 11:44 PM ]

作者: moniuming 时间: 2008-6-19 11:31

好多天无法登陆论坛,今天终于可以了,点击"我的话题"发现全没了,在"我的收藏"中发现了此贴,想想当初的想法确实不够好,今天作了完善,效率更高,而且也不用产生临时文件,在此感谢CN-DOS论坛及帮助过我的各位论坛的朋友,让我得到了进步,再次感谢!!!

@echo off

setlocal enabledelayedexpansion

:again_

echo.

set "yao="

for /l %%a in (0 1 9) do (

   set ming=!random!!random!!random!!random!!random!!random!!random!

   set ming=!ming:~-7!

   echo  !ming!

   set yao=!yao!!ming!

)

echo.

for %%a in (0 1 2 3 4 5 6 7 8 9) do (

   set n=0

   call :count %%a

)

echo.&pause&cls&goto :again_

:count

for /l %%i in (0 1 69) do (

   set fen=!yao:~%%i,1!

   if !fen!==%1 set /a n+=1

)

echo  %1 已经出现 !n! 次

作者: 26933062 时间: 2008-6-19 16:03



@echo off

for /l %%a in (1 1 10) do call :loop

for /l %%a in (0 1 9) do if defined _%%a call echo %%a 出现 %%_%%a%% 次

pause>nul

:loop

  set "var=%random%%random%%random%%random%%random%%random%%random%"

  set "var=%var:~-7%"

  if defined .%var% goto loop

  echo %var%

  set .%var%=a

:loop2

set /a _%var:~0,1%+=1

set var=%var:~1%

if defined var goto loop2

goto :eof

作者: terse 时间: 2008-6-19 16:49

试着生成1000个数字貌似这样效率高



@echo off

setlocal enabledelayedexpansion

for /l %%a in (1 1 1000) do call :loop

for /f "tokens=1,2 delims=.=" %%i in ('set.') do echo %%i 出现 %%j 次

pause

goto :eof

:loop

  set "str=%random%%random%%random%%random%%random%%random%%random%"

  set "str=%str:~-7%"

  if defined %str% goto loop

  echo %str%

  set %str%=a

  for /l %%i in (0 1 6) do set/a .!str:~%%i,1!+=1

作者: moniuming 时间: 2008-6-19 18:21

6,7楼的算法比我的好多了,向你们学习了

作者: moniuming 时间: 2008-6-20 15:36

经测试发现5楼的代码花的时间比6楼和7楼的代码花的时间还要少,有兴趣的朋友可以试试,在我的机子上5楼的平均用时是0.15秒,6楼0.45秒,7楼0.25秒.

作者: terse 时间: 2008-6-20 15:52

Originally posted by moniuming at 2008-6-20 15:36:
经测试发现5楼的代码花的时间比6楼和7楼的代码花的时间还要少,有兴趣的朋友可以试试,在我的机子上5楼的平均用时是0.15秒,6楼0.45秒,7楼0.25秒.

你生成1000组看看而且5楼有重复生成可能排除重复的看看

作者: moniuming 时间: 2008-6-20 16:48

Originally posted by terse at 2008-6-20 15:52:

你生成1000组看看而且5楼有重复生成可能排除重复的看看

确实,当生成1000组的时候看到了差别,最主要是统计的方法,7楼的效率最高,平均才十几秒,6楼的要四十几秒,5楼的效率最差了,汗...,呵呵<img src="images/smilies/face-sad.png" align="absmiddle" border="0"><img src="images/smilies/face-laugh.png" align="absmiddle" border="0"><img src="images/smilies/face-raspberry.png" align="absmiddle" border="0">

作者: bat-zw 时间: 2008-6-20 17:52

也来一个：



@echo off&setlocal enabledelayedexpansion

set t=%time%

:begin

set codes=0 1 2 3 4 5 6 7 8 9

set code=%codes: =%

set /a m+=1,n=10,v=-1

:lp

set /a n-=1,a=%random%%%%n%

set a=!code:~%a%,1!

set str%m%=!str%m%! %a%&set code=!code:%a%=!

if %n% gtr 3 goto lp

for %%a in (%codes%) do (

    set /a v+=1

    for %%i in (!str%m%!) do (

        if %%a equ %%i set /a _!v!+=1

    )

)

if %m% lss 10 goto begin

for /l %%i in (1,1,10) do echo !str%%i!

echo.

for /l %%i in (0,1,9) do echo %%i出现次数为：!_%%i!次

echo 开始时间：%t% 

echo 结束时间：%time%

pause>nul

作者: terse 时间: 2008-6-20 20:29

测试以下的不知道为什么貌似比前面的效率高点



@echo off&setlocal enabledelayedexpansion

for /l %%a in (1 1 10000) do call :loop

    for /f "tokens=1,2 delims=.=" %%i in ('set.') do echo %%i 出现 %%j 次

pause

goto :eof

:loop

  for /l %%i in (1 1 7) do set str=!random:~-1!!str!

  if defined %str% goto loop

  for /l %%i in (0 1 6) do set/a .!str:~%%i,1!+=1

  echo %str%&set str=

作者: moniuming 时间: 2008-6-20 20:53

Originally posted by terse at 2008-6-20 20:29:
测试以下的不知道为什么貌似比前面的效率高点
@echo off&setlocal enabledelayedexpansion

for /l %%a in (1 1 10000) do call :loop

    for /f "tokens=1,2 delims ... 



效率确实提高了一些,原因可能在于生成7个数字的时候吧

作者: bat-zw 时间: 2008-6-21 14:06

简化下我的代码：



@echo off&setlocal enabledelayedexpansion

set t=%time%

:begin

set codes=0 1 2 3 4 5 6 7 8 9

set code=%codes: =%

set /a m+=1,n=10

:lp

set /a n-=1,a=%random%%%%n%

set a=!code:~%a%,1!

for %%i in (%codes%) do if %%i equ %a% set /a _%%i+=1

set str%m%=!str%m%!%a%&set code=!code:%a%=!

if %n% gtr 3 goto lp

echo !str%m%!

if %m% lss 1000 goto begin

echo.

for /l %%i in (0,1,9) do echo %%i出现次数为：!_%%i!次

echo 开始时间：%t% 

echo 结束时间：%time%

pause>nul

Last edited by zw19750516 on 2008-6-21 at 02:09 PM ]