标题: 【已结】如何根据目录名批量更改文件名 [打印本页]
作者: ngd 时间: 2008-1-8 14:48 标题: 【已结】如何根据目录名批量更改文件名
如何根据目录名批量更改文件名?
如文件夹名为：东邪西毒音乐展
如何将此文件夹下的所有mp3文件改名为
东邪西毒音乐展-001.mp3
东邪西毒音乐展-002.mp3
东邪西毒音乐展-003.mp3
……
[ Last edited by ngd on 2008-1-11 at 01:05 PM ]
作者: lxmxn 时间: 2008-1-8 15:06
到批处理室去搜索一下，关键字——“重命名”。
作者: ngd 时间: 2008-1-8 15:21
http://www.cn-dos.net/forum/view ... D%E5%91%BD%E5%90%8D
作者: ngd 时间: 2008-1-10 16:49
CODE: [Copy to clipboard]我要的是批量更改各个目录中图片的文件名@echo off&Setlocal EnableDelayedExpansion
for /f "delims=" %%a in ('dir /ad /b') do (
chdir %%a
for /f "delims=" %%b in ("%cd%") do set new_name=%%~nb
set num=1
for /f "delims=" %%b in ('dir /b *jpg') do (
set /a !num!+=1
if !num! LSS 10 (ren "%%b" "!new_name!-00!num!.jpg") else ren "%%b" "!new_name!-0!num!.jpg"
)
chdir ..
)
论坛中没有现成的
写了点代码但执行不了 问题未解决
作者: everdos 时间: 2008-1-10 20:48 标题: 我用来整理自己的数码相机照片的批处理文件，供参考
===========================
主批处理文件 RENF.BAT
===========================
@echo off
if {%1}=={} goto noparam
set fileprefix=%2
set filenumber=101
for %%I in (%1) do RENF1.BAT "%%I"
set fileprefix=
set filenumber=
goto end
:noparam
echo.
echo Usage: RENF jpgfiles fileprefix
echo.
:end
===========================
被调用的批处理文件 RENF1.BAT
===========================
@echo off
ren %1 %fileprefix%-%filenumber%.jpg
set /a filenumber=filenumber+1
===========================
使用方法：
===========================
RENF myphotos\*.jpg 20080101
可将myphotos目录下的所有jpg文件更改为
20080101-101.jpg
20080101-102.jpg
20080101-103.jpg
......
作者: ngd 时间: 2008-1-10 23:57
多谢 ！ 可这并不是我想要的
如果只是给当前文件夹下图片命名更改一下我的代码就可以
但我这子目录太多了 我要给每个子目录里面的文件按照子目录名进行命名
作者: lxmxn 时间: 2008-1-11 00:52 标题: To ngd: 试试这个吧
CODE: [Copy to clipboard][ Last edited by lxmxn on 2008-1-11 at 12:54 AM ]@echo off & SetLocal EnableDelayedExpansion
for /f "delims=" %%a in ('dir /s/b/a-d *.jpg') do (
for /f "delims=" %%b in ("%%~dpa\.") do (
if not "!_batch!"=="_%%~nb" set _batch=_%%~nb&set num=0&echo....
set /a num+=1
set nums=00!num!
set nums=!nums:~-3!
ren "%%~a" "%%~nb-!nums!%%~xa"
)
)
作者: ngd 时间: 2008-1-11 13:06
o(∩_∩)o... 不错 很好用！ 感激不尽
作者: everdos 时间: 2008-1-11 14:49 标题: 版主好厉害
记得以前用perl可以非常方便地写出这种类似的功能，原来批处理也可以实现。将斑竹的代码改头换面了一下，作为学习的过程，借以领略批处理的强大功能，大家共同进步，呵呵。
@echo off & SetLocal EnableDelayedExpansion
for /f "delims=" %%a in ('dir /s/b/ad') do (
set num=0
echo %%a ....
for /f "delims=" %%b in ('dir /b %%a\*.jpg') do (
set /a num+=1
set nums=00!num!
set nums=!nums:~-3!
ren "%%a\%%b" "%%~na-!nums!.jpg"
)
)
作者: lxmxn 时间: 2008-1-11 15:39 标题: TO everdos
修改得不错,比我的思路清晰多了.
PS:可以把perl的代码发来看看么?
我现在正在看perl方面的东西,如果方便的话,把代码发到lxmxn [AT] gmail.com这个邮箱,我学习学习哈..
[ Last edited by lxmxn on 2008-1-11 at 03:41 PM ]
作者: ngd 时间: 2008-1-11 16:17
原先我也写过和版主类似的代码
for /f "delims=" %%a in ('dir /s/b/a-d *.jpg') do (
for /f "delims=" %%b in ("%%~dpa") do (..........
但提示 “echo已关闭” 无法得到目录名
没想到版主在 %%~dpa 后加了 . 就轻松解决了！
9楼的也不错哈！ 但最好稍作修改，将第5行的 %%a 加上引号，否则遇到某些有空格的目录名就会提示找不到路径。
学到东西了：细节决定成败啊！
CODE: [Copy to clipboard]@echo off & SetLocal EnableDelayedExpansion
for /f "delims=" %%a in ('dir /s/b/ad') do (
set num=0
echo %%a ....
for /f "delims=" %%b in ('dir /b "%%a"\*.jpg') do (
set /a num+=1
set nums=00!num!
set nums=!nums:~-3!
ren "%%a\%%b" "%%~na-!nums!.jpg"
)
)
作者: everdos 时间: 2008-1-11 19:42
| Quote: | |
|
不好意思，老早以前用过perl，只觉得它这方面功能较强大，早就不用了哈，现在电脑里已经没有了
作者: ngd 时间: 2008-1-19 16:17
刚发现 pushd 和 popd 2个命令，将以前写的一段错误代码更正一下，再次感谢everdos和lxmxn两位达人！
CODE: [Copy to clipboard][ Last edited by ngd on 2008-1-19 at 04:26 PM ]@echo off&Setlocal EnableDelayedExpansion
for /f "delims=" %%a in ('dir /ad /b') do (
pushd "%%a"
for /f "delims=" %%b in ("%cd%") do set new_name=%%~nb
set num=0
for /f "delims=" %%b in ('dir /b *jpg') do (
set /a num+=1
set nums=00!num!
set nums=!nums:~-3!
ren "%%b" "!new_name!-!nums!.jpg"
)
popd
)
作者: ngd 时间: 2008-1-20 23:06
CODE: [Copy to clipboard]@echo off&Setlocal EnableDelayedExpansion
for /r %%i in (.) do (
set n=1000
for /f "delims=" %%a in (' dir /b "%%i\*.jpg"') do (
set /a n+=1
ren "%%i\%%a" "%%~ni"-!n:~1!%%~xa
)
)
作者: hhzjxss 时间: 2010-8-20 23:26
谢谢分享，看不懂，只好照用！
弱弱地问一下，最好那段代码最优呢？
作者: ngd 时间: 2010-8-21 08:43
14楼 最简洁