为什么我的程序如果运行到第一个if如果条件为真的时候，总是有The syntax of the command is incorrect.这样的错误

echo Input a file:
set/p INPUTFILE=

if /i "%INPUTFILE%"=="" (
echo 111111111111
set INPUTFILE=Document.txt
goto :END
) else (
echo 222222222222222
if /i not exist %INPUTFILE% (
echo 333333333333
set INPUTFILE=Document.txt
goto :END
)
)

:BEGIN
echo #################
goto :EOF

:END
set INPUTFILE=
echo @@@@@@@@@@@@@@@@@@

以下是XP自带的帮助信息，自己也没怎么在意过，一起学习吧。
ELSE 子句必须在 IF 之后出现在同一行上。例如:

IF EXIST filename. (
del filename.
) ELSE (
echo filename. missing.
)

因为 del 命令需要用一个新行终止，以下子句不会有效:

IF EXIST filename. del filename. ELSE echo filename. missing

由于 ELSE 命令必须与 IF 命令的尾端在同一行上，以下子句也
不会有效:

IF EXIST filename. del filename.
ELSE echo filename. missing

如果都放在同一行上，以下子句有效:

IF EXIST filename. (del filename.) ELSE echo filename. missing

搞错了，LZ的问题在于变量没有延迟，改成如下即可：
setlocal enabledelayedexpansion
echo Input a file:
set/p INPUTFILE=

if /i "!INPUTFILE!"=="" (
echo 111111111111
set INPUTFILE=Document.txt
goto :END
) else (
echo 222222222222222
if not exist !INPUTFILE! (
echo 333333333333
set INPUTFILE=Document.txt
goto :END
)

)

:BEGIN
echo #################
goto :EOF

:END
set INPUTFILE=
echo @@@@@@@@@@@@@@@@@@

lz可以搜索一下关于变量延迟的帖子，够你学习一阵子了。

问题出在else分句的%INPUTFILE%上面，谨记批处理的%%这些变量是会在整个命令执行前就进行替换，之后才执行（开启变量延迟后的!!变量则不同）；
而当提示输入时你按了回车，%INPUTFILE%为空，系统执行时变成了
if /i not exist (
这样就出现语法错误了，在两旁加上双引号之类的就可以了；
另外if exist可以不用加/i参数

echo Input a file:

set/p INPUTFILE=



if /i "%INPUTFILE%"=="" (

        echo        111111111111

        set INPUTFILE=Document.txt

        goto :END

) else (

        echo        222222222222222

        if not exist "%INPUTFILE%" (

                echo        333333333333

                set INPUTFILE=Document.txt

                goto :END

        )

)



:BEGIN                

echo        #################

pause

goto :EOF



:END

set INPUTFILE=

echo        @@@@@@@@@@@@@@@@@@ 

pause

Last edited by dikex on 2007-11-2 at 10:09 PM ]

太感谢3#，4#了，哈哈，一语惊醒梦中人啊！回3#的，我看了一遍就明白了哈！

Last edited by OverThere on 2007-11-3 at 01:52 AM ]