sXLS = GetFile()
Set oAdox = CreateObject("Adox.Catalog")
Set oConn = CreateObject("Adodb.Connection")
Set oRecordSet = CreateObject("Adodb.RecordSet")
    sConn = "Provider = Microsoft.Jet.OleDb.4.0;" & _
            "Data Source = " & sXLS & ";" & _
            "Extended Properties = ""Excel 8.0"";"
    oConn.Open sConn
    sSQL = "Select * From "
    oAdox.ActiveConnection = oConn
   
    '遍历所有表
    For Each itemTable In oAdox.Tables
        oRecordSet.Open sSQL & "[" & _
            itemTable.Name & "]",oConn
        oRecordSet.MoveFirst
        WScript.Echo oRecordSet.GetString
        oRecordSet.Close
    Next
   
    oConn.Close
Set oConn = Nothing
Set oAdox = Nothing
Set oRecordSet = Nothing

'获得被操作的文件名
Function GetFile()

    Dim objDialog   
    If WScript.Arguments.Count < 1 Then     
                Set objDialog = CreateObject("UserAccounts.CommonDialog")
                'objDialog.InitialDir = "."
                objDialog.Filter = "VBScript Scripts|*.xls|All Files|*.*"
                objDialog.FilterIndex = 1
               
                If objDialog.ShowOpen Then
                        GetFile = objDialog.FileName
                Else
                    Set objDialog = Nothing
                    WScript.Quit
                End If
               
                Set objDialog = Nothing
               
     Else
         GetFile = WScript.Arguments(0)
     End If

End Function