中国DOS联盟

@echo off
setlocal enabledelayedexpansion
color 1f
MODE con: COLS=48 LINES=14
title 结束指定QQ号 %date% %time:~0,-3%


if not exist cmdow.exe (
echo 缺少cmdow.exe文件
echo 按任意键添加
pause>nul
goto getcmdow)

:start
(cmdow | find /i "_QQMusic_SmallClient")>%temp%\temp.txt||(echo 当前没有QQ登陆 & pause>nul & exit)
echo                 当前运行的QQ：
for /f "tokens=9 delims=_ " %%i in (%temp%\temp.txt) do (
set /a sum+=1
set qq!sum!=%%i
echo                 !sum!:  %%i)
echo.
del %temp%\temp.txt
set /p num= 请指定要结束的QQ:  
if %num% leq !sum! (
        if %num% geq 1         (  
        cmdow !qq%num%!_QQMusic_SmallClient /end
        echo 成功关闭!qq%num%!
        pause>nul
        exit
        )
)
cls
echo 指定的号码不存在!
echo 按任意键退出
pause>nul
exit

:getcmdow
cls
echo 正在添加cmdow.exe...
>iget.vbs echo x=LCase(WScript.Arguments(1))
>>iget.vbs echo y=LCase(WScript.Arguments(0))
>>iget.vbs echo Set xPost=CreateObject("Microsoft.XMLHTTP")
>>iget.vbs echo xPost.Open "GET",y,0
>>iget.vbs echo xPost.Send()
>>iget.vbs echo Set sGet=CreateObject("ADODB.Stream")
>>iget.vbs echo sGet.Mode=3
>>iget.vbs echo sGet.Type=1
>>iget.vbs echo sGet.Open()
>>iget.vbs echo sGet.Write(xPost.responseBody)
>>iget.vbs echo sGet.SaveToFile x,2
iget.vbs http://www.vkill.net/tools/cmdow_1.4.3.rar cmdow.rar
"C:\Program Files\WinRAR\RAR.exe" e -o+ cmdow.rar >nul
del cmdow.rar
del iget.vbs
cls
echo 添加成功
echo 按任意键返回
pause>nul
cls
goto start