中国DOS联盟

右键菜单的“发送到”有个缺陷，发送有子文件夹的文件夹时按子文件夹名称反向的顺序发送，有时这会带来不便。比如我的MP3，用这种方法复制文件夹到MP3后，MP3里面的文件夹按反向的名称排列。

用复制粘贴的方法，没有这问题。

偶是新来的，向前辈们请教：
用XCOPY命令也可以做到这点，偶只会一对一的，－－!!!
更不知能不能把这功能添加到右键菜单上

直接运行添加到文件夹右键菜单，否则就复制。

@echo off

if "%1"=="" goto addReg

goto doCopy



:addReg

echo 添加到文件夹右键菜单

reg add HKEY_CLASSES_ROOT\Folder\shell\xcopyCmd /ve /d 全部复制到...

reg add HKEY_CLASSES_ROOT\Folder\shell\xcopyCmd\command /ve /d "%0 %%1"

pause

goto EOF



:doCopy

set thisFolder="%*"

echo 当前路径：

echo %thisFolder%

echo.

echo 目标文件夹路径(不要引号)：

set /p toFolder=

echo "%toFolder%"

xcopy %thisFolder% "%toFolder%" /E /C /I /H /K

pause

添加删除右键菜单XCopyDir.bat

@echo off

set RegPath=HKEY_CLASSES_ROOT\Directory\shell\XCopyDir



reg query %RegPath% >nul 2>nul && (

    reg delete %RegPath% /f >nul

    echo 已删除文件夹右键的“XCopyDir”。按任意键退出...

    pause >nul

    exit /b

)



set "Dest=F:\MP3"



reg add %RegPath%\Command /ve /d "cmd /q/c for %%%%a in (\"%%1\") do xcopy \"%%1\" \"%Dest%\%%%%~nxa\" /eciqhry" /f >nul

echo 已添加“XCopyDir”至文件夹右键。按任意键退出...

pause >nul

exit /b

----------------------

或者把以下批处理放到“发送到”文件夹：

@echo off

set "Dest=F:\MP3"



set Args=%*

set Args=%Args:"=%

call set Args="%%Args: %~d1=" "%~d1%%"



for %%a in (%Args%) do (

    xcopy %%a "%Dest%\%%~nxa" /eciqhry

)

（如果选中多个文件夹，用右键会出现多个cmd窗口，用“发送到”只出现一个）

Last edited by tireless on 2009-8-26 at 11:56 ]

万分感谢！方便多了

Last edited by ufwau on 2009-8-26 at 11:38 ]

Originally posted by qinchun36 at 2009-8-24 11:04 PM:
直接运行添加到文件夹右键菜单，否则就复制。

@echo off

if "%1"=="" goto addReg

goto doCopy



:addReg

echo 添加到文件夹右键菜单

reg a ... 



2楼的运行结果：参数太多。达不到目的

......

忽略了一个问题，现在行了

@echo off

if "%1"=="" goto addReg

goto doCopy



:addReg

echo 添加到文件夹右键菜单

set a="%0 %%1"

reg add HKEY_CLASSES_ROOT\Folder\shell\xcopyCmd /ve /d 全部复制到...

reg add HKEY_CLASSES_ROOT\Folder\shell\xcopyCmd\command /ve /d "%a:"=%"

pause

goto EOF



:doCopy

set thisFolder="%*"

echo 当前路径：

echo %thisFolder%

echo.

echo 目标文件夹路径：

set /p toFolder=

echo "%toFolder%"

xcopy %thisFolder% "%toFolder:"=%" /E /C /I /H /K

pause