中国DOS联盟

我想请问一下如何把广本中的按TAb键形成的字符给替换成逗号

我有一个文本文件,里面的格式是这样的
101B0001ST 12345(101B0001ST和 12345中间是按一次TAB键形成的空格)
102B0022AB 223
........(注:其中前面的部分是定长的,后面的数据是不定长的)
我现在需要把这个内容转换成这样:
101B0001ST,12345
102B0022AB,223
......
我应该怎么办?
我当时的思路是用for来截取,可是做得不成功,我当时的做的批处理是这样,大家帮忙看看到底错在哪里?
@echo off
FOR /f %%i in (1.txt) do (for /f "tokens=2 delims= " %%c in (1.txt) do (echo %%i,%%c))
但是显示的结果却是这样,多了很多不该有的东西...
101B0001ST,12345
101B0001ST,223
102B0022AB,12345
102B0022AB,223
用字符替换又不知道TAB键形成的字符该怎么办?请大家帮帮忙?

@echo off

for /f "delims=" %%a in (1.txt) do (

   set "str=%%a"

   call set "str1=%%str:~,10%%"

   call set "str2=%%str:~11%%"

   call echo %%str1%%,%%str2%%

)

pause

Last edited by moniuming on 2008-6-2 at 10:12 AM ]

我想请问一下,为什么DO 后面的三行全部都用CALL吗?谢谢

变量延迟,其实也可以用下面的代码

@echo off

setlocal enabledelayedexpansion

for /f "delims=" %%a in (1.txt) do (

   set "str=%%a"

   set "str1=!str:~,10!"

   set "str2=!str:~11!"

   echo !str1!,!str2!

)

pause

@echo off

type nul>"C:\test\b.txt"

for /f "usebackq tokens=1,2 delims=	" %%a in ("C:\test\a.txt") do (

  >>"C:\test\b.txt" echo %%a,%%b

)